kogiku/kogiku/kogiku.el

;;; kogiku.el - reading file and directory names with migemo service

;; Copyright (C) 2004 Masatake YAMATO and Hideyuki SHIRAI

;; Author: Masatake YAMATO <jet@gyve.org> and
;;         Hideyuki SHIRAI  <shirai@meadowy.org>

;; This file is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; This file is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to
;; the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:
;; ?ユ??????＜?ゃ???????ュ????migemo??篏帥?ｃ??亜?????????????違?????с????

;; (篁???戎?ｃ???????????с??????)篁ュ??windows??eadow??篏帥?ｃ??????????????
;; ?????鴻????????(絎?????????茹?)?????吟?＜?障???????????＜?ゃ????find-file??
;; ????????????篁???羲√?紊?????綽?荀???????)???＜?ゃ????????絎?????絽吾???√????/span>
;; ???????????障??????"desukutoxtupu"?????泣???????????????鴻???????????後???
;; ????return]?с???ｃ????絎????????????с???障??????

;; ?????鴻??????????????絎??????????違??"desktop"???? "de"[tab]?????ф?????/span>
;; ???違?????????????障??????鐚?migemo??篏帥???違??????絎??障???????????с??????
;; ?с????"desktop"??"de"??migemo?ф?ユ????????????絮???羝??帥?????帥?若?潟??
;; ?上???????ｃ???????????????????????＜?ゃ???????????у???????違?????＜?ゃ????
;; ????絎?("desktop"???????鴻???????????????????????茖?絎???茖???????
;; ("de"???????鴻????????????????????????????????с???障????

;; kogiku.el??igemo.el????NU Emacs 21???絖????????障????migemo.el??/span>
;; ??篏????障??腆肴????????????kogiku.el?????若?????鴻?????ｃ?????ｃ??????
;; ???ｃ??????????舟??.emacs? (require 'kogiku)???吾????????macs????
;; 莎桁?????障????migemo? http://migemo.namazu.rog ?????ユ???с???障????

;;; Acknowledgments:

;; Some code used in `kogiku-file-name-completion'
;; and `kogiku-try-completion-regexp' are copied from
;; http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=kogiku
;; (MeadowMemo maintained by Akihisa Matsushita <akihisa@mail.ne.jp>).

;; `kogiku-read-file-name-internal' are
;; translated from emacs/src/fileio.c::read-file-name-internal
;; in elisp.

;;; Version:
;; 2.0.2.

;;; History:
;; 2.0.2
;; -- inlucde shirai's patch
;; -- introduce custom
;;
;; 2.0.1 -- update `Acknowledgments'.
;;
;; 2.0 -- rewrite.

;;; Code:

(eval-when-compile
  (require 'cl)
  (require 'migemo))

(defgroup kogiku nil
  "reading file and directory name with migemo service"
  :group 'convenience)

(defcustom kogiku-enable-once nil
  "*If non-nil, kogiku effects a one time when call with a prefix argument.
If nil, kogiku toggle with a prefix argument."
  :group 'kogiku
  :type 'boolean)

(defcustom kogiku-mode-change-key "\M-k"
  "*Key of change `kogiku-enable-once'."
  :group 'kogiku
  :type 'sexp)

(defcustom kogiku-take-over-targets '(read-file-name-internal
                                      ffap-read-file-or-url-internal)
  "*絨???????ｃ????`minibuffer-completion-table'??┏蕁???
minibuffer???九勝??腱祉?ｃ????????/span>`minibuffer-completion-table'???ゃ??
`kogiku-take-over-targets'???膣??с?????違??絨????????茖?絎????????茵???????"
  :group 'kogiku
  :type '(repeat symbol))

(defcustom kogiku-minibuffer-prompt-string "kogiku"
  "*Kogiku indicator in minibuffer."
  :group 'kogiku
  :type 'string)

(defcustom kogiku-minibuffer-indicator-strings '("ON" "off" "ONESHOT")
  "*Indicators in minibuffer prpmpt."
  :group 'kogiku
  :type '(list (string :tag "Toggle-mode ON")
               (string :tag "Toggle-mode off")
               (string :tag "Oneshot-mode")))

(defface kogiku-indicator-face
  '((((class color) (type tty)) (:foreground "blue" :bold t))
    (((class color) (background light)) (:foreground "dark blue" :bold t))
    (((class color) (background dark))  (:foreground "cyan" :bold t))
    (t (:bold t)))
  "*Face of kogiku indicator."
  :group 'kogiku)

(defvar kogiku-original-functions nil)
(defvar kogiku-original-completion-tables nil)

(defvar kogiku-completion-key "\t")
(defvar kogiku-minibuffer-prompt-overlay nil)
(defvar kogiku-mode-change-original-functions nil)

(defvar kogiku-emacs21-p (fboundp 'field-beginning))

(defun kogiku-complete (&optional arg)
  (interactive "P")
  (if kogiku-enable-once
      (kogiku-oneshot-complete arg)
    (kogiku-complete-with-toggle arg)))

(defun kogiku-oneshot-complete (fire)
  (let ((minibuffer-completion-table minibuffer-completion-table))
    (when fire
      (setq minibuffer-completion-table 'kogiku-read-file-name-internal))
    (prog1
        (funcall (car kogiku-original-functions))
      (kogiku-minibuffer-prompt))))

(defun kogiku-complete-with-toggle (switch)
  (cond
   ((and switch
         (eq minibuffer-completion-table 'kogiku-read-file-name-internal))
    (setq minibuffer-completion-table (car kogiku-original-completion-tables))
    (kogiku-minibuffer-prompt))
   (switch
    (setq minibuffer-completion-table 'kogiku-read-file-name-internal)
    (kogiku-minibuffer-prompt)))
  (prog1
      (funcall (car kogiku-original-functions))
    (kogiku-minibuffer-prompt)))

(defvar kogiku-minibuffer-prompt-map nil
  "kogiku prompt map for mode change.")

(let ((map (make-sparse-keymap)))
  (define-key map [mouse-2] 'kogiku-mode-change-at-mouse)
  (setq kogiku-minibuffer-prompt-map map))

(defun kogiku-minibuffer-prompt ()
  (let* ((mode (cond
                (kogiku-enable-once
                 (nth 2 kogiku-minibuffer-indicator-strings))
                ((eq minibuffer-completion-table 'kogiku-read-file-name-internal)
                 (nth 0 kogiku-minibuffer-indicator-strings))
                (t
                 (nth 1 kogiku-minibuffer-indicator-strings))))
         (indicator
          (if kogiku-emacs21-p
              (format "[%s:%s] " kogiku-minibuffer-prompt-string mode)
            (format "%s(%s): " kogiku-minibuffer-prompt-string mode)))
         (max (if kogiku-emacs21-p (1+ (point-min)) (point-max))))
    (when kogiku-emacs21-p
      (add-text-properties 0 (1- (length indicator))
                           '(face kogiku-indicator-face)
                           indicator)
      (add-text-properties 0 (length indicator)
                           `(local-map 
                             ,kogiku-minibuffer-prompt-map 
                             mouse-face
                             highlight)
                           indicator))
    (if kogiku-minibuffer-prompt-overlay
        (move-overlay kogiku-minibuffer-prompt-overlay
                      (point-min) max)
      (setq kogiku-minibuffer-prompt-overlay
            (make-overlay (point-min) max)))
    (overlay-put kogiku-minibuffer-prompt-overlay
                 'before-string indicator)
    (overlay-put kogiku-minibuffer-prompt-overlay 'evaporate t)
    indicator))

(if (fboundp 'compare-strings)
    (defalias 'kogiku-compare-strings 'compare-strings)
  (defun kogiku-compare-strings (string1 start1 end1 string2 start2 end2)
    "Convenience `compare-strings' for XEmacs."
    (let* ((str1 (substring string1 start1 end1))
           (str2 (substring string2 start2 end2))
           (len (min (length str1) (length str2)))
           (i 0))
      (if (string= str1 str2)
          t
        (setq i (catch 'ignore
                  (while (< i len)
                    (when (not (eq (aref str1 i) (aref str2 i)))
                      (throw 'ignore i))
                    (setq i (1+ i)))
                  i))
        (1+ i)))))

(defun kogiku-try-completion-regexp (regexp all-list)
  (if (= (length regexp) 0)
      ""
    (substring
             (car all-list)
             0
             (apply 'min
                    (mapcar
                     (lambda (a)
                       (apply 'min
                              (mapcar
                               (lambda (b)
                                 (- (abs
                                     (kogiku-compare-strings a 0 nil
                                                      b 0 nil))
                                    1))
                               (delete a all-list))))
                     all-list)))))

(defun kogiku-migemo-get-pattern (string)
  (let ((migemo-pattern-alist migemo-pattern-alist)
        (migemo-white-space-regexp " *"))
    (let ((case-fold-search nil))
      (while (string-match "[^a-zA-Z]\\([a-z]+\\)" string)
        (setq string
              (replace-match (capitalize (match-string 1 string)) nil nil string 1))))
    (migemo-get-pattern string)))

(defun kogiku-file-name-completion (string dir &optional all)
  (let* ((expanded-string (expand-file-name string dir))
         (files (directory-files dir))
         (pattern
          (if (string-match "/$" expanded-string)
              ""
            (concat "^\\("
                    (cond
                     ((string-match "\\cj$" string)
                      string)
                     ((string-match "^\\(\\(\\Cj*\\)?\\cj+\\)\\(\\Cj+\\)$" string)
                      (concat (match-string 1 string)
                              "\\("
                              (kogiku-migemo-get-pattern (match-string 3 string))
                              "\\)"))
                     (t
                      (kogiku-migemo-get-pattern (file-name-nondirectory string))))
                    "\\)")))
         (candidates (delete nil
                            (mapcar
                             (lambda (f)
                               (if (string-match pattern f)
                                   (if (file-directory-p (expand-file-name f dir))
                                       ;; ???ｃ????????? / ?х??????????/span>
                                       (file-name-as-directory f)
                                     f)))
                             files)))
         (count (length candidates))
         common)
    (if all
        candidates
      (cond
       ((eq count 0) nil)
       ((eq count 1) (let ((candidate (car candidates)))
                       (if (file-directory-p candidate)
                           (file-name-as-directory candidate)
                         candidate)))
       (t
        (if (null (delete nil (mapcar (lambda (candidate)
                                        (string-match "\\cj" candidate))
                                      candidates)))
            ;; ????????茖????ユ??????????с???????翫??????絽檎????
            ;; `try-completion' ???若???с?障????????
            (try-completion string (mapcar 'list candidates))
          (setq common (kogiku-try-completion-regexp pattern candidates))
          (if (eq (length common) 0) string common)))))))

(defun kogiku-file-name-all-completions (string dir)
  (kogiku-file-name-completion string dir t))

(defun kogiku-double-dollars (input)
  (let ((ret ""))
    (while (string-match "\\$" input)
      (setq ret (concat ret
                        (substring input 0 (match-beginning 0))
                        "$$"))
      (setq input (substring input (match-end 0))))
    (concat ret input)))

(defun kogiku-read-file-name-internal (string dir action)
  (block nil
    (unless (boundp 'read-file-name-predicate)
      (setq read-file-name-predicate nil))
    (let ((realdir dir)
          (name string)
          (orig-string)
          (changed 0)
          (val)
          (specdir))
      (if (eq 0 (length string))
          (if (eq action 'lambda)
              (return nil))
        (setq orig-string string)
        (setq string (substitute-in-file-name string))
        (setq changed (null (string-equal string orig-string)))
        (setq name (file-name-nondirectory string))
        (setq val  (file-name-directory string))
        (if (not (null val))
            (setq realdir (expand-file-name val realdir))))
      (cond
       ((null action)
        (setq specdir (file-name-directory string))
        (setq val     (kogiku-file-name-completion name realdir))
        (return (if (not (stringp val))
                    (if changed
                        (kogiku-double-dollars string)
                      val)
                  (if (not (null specdir))
                      (setq val (concat specdir val)))
                  (kogiku-double-dollars val))))
       ((eq action t)
        (let ((all (kogiku-file-name-all-completions name realdir)))
          (unless (or (null read-file-name-predicate)
                      (eq read-file-name-predicate 'file-exists-p))
            (delete-if (lambda (x)
                         (not (funcall read-file-name-predicate x)))
                       all))
          (return all)))
       ((eq action 'lambda)
        (return (if read-file-name-predicate
                    (funcall read-file-name-predicate string)
                  (file-exists-p string))))))))

(defun kogiku-mode-change-at-mouse (event)
  (interactive "e")
  (save-window-excursion
    (save-excursion
      (set-buffer (window-buffer (posn-window (event-end event))))
      (kogiku-mode-change))))

(defun kogiku-mode-change ()
  (interactive)
  ;; Cyclic: on-off, off->oneshot, oneshot->on
  (let ((nextmode (cond 
                   (kogiku-enable-once 'on)
                   ((eq minibuffer-completion-table
                        'kogiku-read-file-name-internal) 'off)
                   (t 'oneshot))))
    (cond
     ((eq nextmode 'on)
      (setq kogiku-enable-once nil)
      (setq minibuffer-completion-table 'kogiku-read-file-name-internal))
     ((eq nextmode 'off)
      (setq kogiku-enable-once nil)
      (setq minibuffer-completion-table (car kogiku-original-completion-tables)))
     (t ;; oneshot
      (setq kogiku-enable-once t)
      (setq minibuffer-completion-table (car kogiku-original-completion-tables))))
    (kogiku-minibuffer-prompt)))

(defun kogiku-install-key ()
  (when (memq minibuffer-completion-table kogiku-take-over-targets)
    (let ((table (car kogiku-original-completion-tables))
          (func (lookup-key (current-local-map) kogiku-completion-key))
          (cfunc (lookup-key (current-local-map) kogiku-mode-change-key)))
      (if (eq func 'kogiku-complete)
          (progn
            (push table kogiku-original-completion-tables)
            (push (car kogiku-original-functions)
                  kogiku-original-functions)
            (push (car kogiku-mode-change-original-functions)
                  kogiku-mode-change-original-functions))
        (push minibuffer-completion-table kogiku-original-completion-tables)
        (push func kogiku-original-functions)
        (push cfunc kogiku-mode-change-original-functions))
      (define-key (current-local-map) kogiku-completion-key 'kogiku-complete)
      (define-key (current-local-map) kogiku-mode-change-key 'kogiku-mode-change)
      (kogiku-minibuffer-prompt))))

(add-hook 'minibuffer-setup-hook 'kogiku-install-key)

(defun kogiku-uninstall-key ()
  (when (and (or (eq minibuffer-completion-table 'kogiku-read-file-name-internal)
                 (memq minibuffer-completion-table kogiku-take-over-targets))
             (eq (lookup-key (current-local-map) kogiku-completion-key)
                 'kogiku-complete))
    (pop kogiku-original-completion-tables)
    (define-key (current-local-map) kogiku-completion-key (pop kogiku-original-functions))
    (when (eq (lookup-key (current-local-map) kogiku-mode-change-key)
              'kogiku-mode-change)
      (define-key (current-local-map) kogiku-mode-change-key
        (pop kogiku-mode-change-original-functions)))))

(add-hook 'minibuffer-exit-hook 'kogiku-uninstall-key)

(provide 'kogiku)
;; kogiku.el ends here