kogiku/kogiku/kogiku.el

;;; kogiku.el - reading file and directory names with migemo service

;; Copyright (C) 2004 Masatake YAMATO

;; Author: Masatake YAMATO <jet@gyve.org>

;; This file is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; This file is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to
;; the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:
;; ?ユ??????＜?ゃ???????ュ????migemo??篏帥?ｃ??亜?????????????違?????с????

;; (篁???戎?ｃ???????????с??????)篁ュ??windows??eadow??篏帥?ｃ??????????????
;; ?????鴻????????(絎?????????茹?)?????吟?＜?障???????????＜?ゃ????find-file??
;; ????????????篁???羲√?紊?????綽?荀???????)???＜?ゃ????????絎?????絽吾???√????/span>
;; ???????????障??????"desukutoxtupu"?????泣???????????????鴻???????????後???
;; ????return]?с???ｃ????絎????????????с???障??????

;; ?????鴻??????????????絎??????????違??"desktop"???? "de"[tab]?????ф?????/span>
;; ???違?????????????障??????鐚?migemo??篏帥???違??????絎??障???????????с??????
;; ?с????"desktop"??"de"??migemo?ф?ユ????????????絮???羝??帥?????帥?若?潟??
;; ?上???????ｃ???????????????????????＜?ゃ???????????у???????違?????＜?ゃ????
;; ????絎?("desktop"???????鴻???????????????????????茖?絎???茖???????
;; ("de"???????鴻????????????????????????????????с???障????

;; kogiku.el??igemo.el????NU Emacs 21???絖????????障????migemo.el??/span>
;; ??篏????障??腆肴????????????kogiku.el?????若?????鴻?????ｃ?????ｃ??????
;; ???ｃ??????????舟??.emacs? (require 'kogiku)???吾????????macs????
;; 莎桁?????障????migemo? http://migemo.namazu.rog ?????ユ???с???障????

;;; Acknowledgments:

;; Some code used in `kogiku-file-name-completion' 
;; and `kogiku-try-completion-regexp' are copied from 
;; http://www.bookshelf.jp/cgi-bin/goto.cgi?file=meadow&node=kogiku
;; (MeadowMemo maintained by Akihisa Matsushita <akihisa@mail.ne.jp>).

;; `kogiku-read-file-name-internal' are
;; translated from emacs/src/fileio.c::read-file-name-internal 
;; in elisp.

;;; Version:
;; 2.0.2.

;;; History:
;; 2.0.2
;; -- inlucde shirai's patch
;; -- introduce custom
;;
;; 2.0.1 -- update `Acknowledgments'.
;;
;; 2.0 -- rewrite.

;;; Code:

(eval-when-compile 
  (require 'cl)
  (require 'migemo))

(defgroup kogiku nil
  "reading file and directory name with migemo service"
  :group 'convenience)

(defcustom kogiku-minibuffer-prompt-string "kogiku"
  "*Kogiku indicator in minibuffer."
  :group 'kogiku
  :type 'string)

(defcustom kogiku-enable-once nil
  "*If non-nil, kogiku effects a one time when call with a prefix argument.
If nil, kogiku toggle with a prefix argument."
  :group 'kogiku
  :type 'boolean)

(defvar kogiku-original-function nil)
(defvar kogiku-completion-key "\t")

(defun kogiku-complete (&optional arg)
  (interactive "P")
  (if kogiku-enable-once
      (kogiku-oneshot-complete arg)
    (kogiku-complete-with-toggle arg)))

(defun kogiku-oneshot-complete (fire)
  (let ((minibuffer-completion-table minibuffer-completion-table))
    (when fire
      (setq minibuffer-completion-table 'kogiku-read-file-name-internal))
    (funcall kogiku-original-function)))

(defun kogiku-complete-with-toggle (switch)
  (cond
   ((and switch
         (eq minibuffer-completion-table 'read-file-name-internal))
    (setq minibuffer-completion-table 'kogiku-read-file-name-internal)
    (kogiku-minibuffer-prompt-e21))
   ((and switch
         (eq minibuffer-completion-table 'kogiku-read-file-name-internal))
    (setq minibuffer-completion-table 'read-file-name-internal)
    (kogiku-minibuffer-prompt-e21)))
  (funcall kogiku-original-function)
  (kogiku-minibuffer-prompt-not-e21))

(defun kogiku-minibuffer-prompt-e21 ()
  (when (fboundp 'field-beginning)
    (let ((prompt (buffer-substring (point-min) (field-beginning)))
          (buffer-read-only nil)
          (inhibit-read-only t)
          (props (text-properties-at (point-min))))
      (save-excursion
        (when (string-match ":[^:]*" prompt)
          (setq prompt (concat (substring prompt 0 (match-beginning 0))
                               (format " (%s)" kogiku-minibuffer-prompt-string)
                               (substring prompt (match-beginning 0))))
          (set-text-properties 0 (length prompt) props prompt)
          (delete-region (point-min) (field-beginning))
          (goto-char (point-min))
          (insert prompt))))))

(defvar kogiku-minibuffer-prompt-overlay nil)

(defun kogiku-minibuffer-prompt-not-e21 ()
  (unless (fboundp 'field-beginning)
    (when (eq minibuffer-completion-table 'kogiku-read-file-name-internal)
      (if kogiku-minibuffer-prompt-overlay
          (move-overlay kogiku-minibuffer-prompt-overlay
                        (point-min) (1+ (point-min)))
        (setq kogiku-minibuffer-prompt-overlay
              (make-overlay (point-min) (1+ (point-min)))))
      (overlay-put kogiku-minibuffer-prompt-overlay
                   'before-string
                   (format "%s: " kogiku-minibuffer-prompt-string))
      (overlay-put kogiku-minibuffer-prompt-overlay 'evaporate t))))
  
(if (fboundp 'compare-strings)
    (defalias 'kogiku-compare-strings 'compare-strings)
  (defun kogiku-compare-strings (string1 start1 end1 string2 start2 end2)
    "Convenience `compare-strings' for XEmacs."
    (let* ((str1 (substring string1 start1 end1))
           (str2 (substring string2 start2 end2))
           (len (min (length str1) (length str2)))
           (i 0))
      (if (string= str1 str2)
          t
        (setq i (catch 'ignore
                  (while (< i len)
                    (when (not (eq (aref str1 i) (aref str2 i)))
                      (throw 'ignore i))
                    (setq i (1+ i)))
                  i))
        (1+ i)))))

(defun kogiku-try-completion-regexp (regexp all-list)
  (if (= (length regexp) 0) 
      ""
    (let (common)
      (setq common
            (substring
             (car all-list) 
             0
             (apply 'min 
                    (mapcar
                     (lambda (a)
                       (apply 'min 
                              (mapcar 
                               (lambda (b)
                                 (- (abs 
                                     (kogiku-compare-strings a 0 nil
                                                      b 0 nil))
                                    1))
                               (delete a all-list))))
                     all-list))))
      common)))

(defun kogiku-migemo-get-pattern (string)
  (let ((migemo-pattern-alist migemo-pattern-alist)
        (migemo-white-space-regexp " *"))
    (let ((case-fold-search nil))
      (while (string-match "[^a-zA-Z]\\([a-z]+\\)" string)
        (setq string
              (replace-match (capitalize (match-string 1 string)) nil nil string 1))))
    (migemo-get-pattern string)))

(defun kogiku-file-name-completion (string dir &optional all)
  (let* ((expanded-string (expand-file-name string dir))
         (files (directory-files dir))
         (pattern
          (if (string-match "/$" expanded-string)
              ""
            (concat "^\\("
                    (cond
                     ((string-match "\\cj$" string)
                      string)
                     ((string-match "^\\(\\(\\Cj*\\)?\\cj+\\)\\(\\Cj+\\)$" string)
                      (concat (match-string 1 string)
                              "\\("
                              (kogiku-migemo-get-pattern (match-string 3 string))
                              "\\)"))
                     (t
                      (kogiku-migemo-get-pattern (file-name-nondirectory string))))
                    "\\)")))
         (candidates (delete nil
                            (mapcar
                             (lambda (f)
                               (if (string-match pattern f)
                                   (if (file-directory-p (expand-file-name f dir))
                                       ;; ???ｃ????????? / ?х??????????/span>
                                       (file-name-as-directory f)
                                     f)))
                             files)))
         (count (length candidates))
         common)
    (if all
        candidates
      (cond
       ((eq count 0) nil)
       ((eq count 1) (let ((candidate (car candidates)))
                       (if (file-directory-p candidate)
                           (file-name-as-directory candidate)
                         candidate)))
       (t
        (if (null (delete nil (mapcar (lambda (candidate)
                                        (string-match "\\cj" candidate))
                                      candidates)))
            ;; ????????茖????ユ??????????с???????翫??????絽檎????
            ;; `try-completion' ???若???с?障????????
            (try-completion string (mapcar 'list candidates))
          (setq common (kogiku-try-completion-regexp pattern candidates))
          (if (eq (length common) 0) string common)))))))

(defun kogiku-file-name-all-completions (string dir)
  (kogiku-file-name-completion string dir t))

(defun kogiku-double-dollars (input)
  (let ((ret ""))
    (while (string-match "\\$" input)
      (setq ret (concat ret
                        (substring input 0 (match-beginning 0))
                        "$$"))
      (setq input (substring input (match-end 0))))
    (concat ret input)))

(defun kogiku-read-file-name-internal (string dir action)
  (block nil
    (unless (boundp 'read-file-name-predicate)
      (setq read-file-name-predicate nil))
    (let ((realdir dir)
          (name string)
          (orig-string)
          (changed 0)
          (val)
          (specdir))
      (if (eq 0 (length string))
          (if (eq action 'lambda)
              (return nil))
        (setq orig-string string)
        (setq string (substitute-in-file-name string))
        (setq changed (null (string-equal string orig-string)))
        (setq name (file-name-nondirectory string))
        (setq val  (file-name-directory string))
        (if (not (null val))
            (setq realdir (expand-file-name val realdir))))
      (cond
       ((null action)
        (setq specdir (file-name-directory string))
        (setq val     (kogiku-file-name-completion name realdir))
        (return (if (not (stringp val))
                    (if changed 
                        (kogiku-double-dollars string)
                      val)
                  (if (not (null specdir)) 
                      (concat specdir val)
                    (kogiku-double-dollars val)
                    ))))
       ((eq action t)
        (let ((all (kogiku-file-name-all-completions name realdir)))
          (unless (or (null read-file-name-predicate)
                      (eq read-file-name-predicate 'file-exists-p))
            (delete-if (lambda (x) 
                         (not (funcall read-file-name-predicate x))
                         all)))
          (return all)))
       ((eq action 'lambda)
        (return (if read-file-name-predicate
                    (funcall read-file-name-predicate string)
                  (file-exists-p string))))))))

(defun kogiku-install-key ()
  (when (eq minibuffer-completion-table 'read-file-name-internal)
    (setq kogiku-original-function
          (let ((tmp (lookup-key (current-local-map) kogiku-completion-key)))
            (cond
             ((null tmp)
              'minibuffer-complete)
             ((eq tmp 'kogiku-complete)
              (and kogiku-original-function 'minibuffer-complete))
             (t
              tmp))))
    (define-key (current-local-map) kogiku-completion-key 'kogiku-complete)))
(add-hook 'minibuffer-setup-hook 'kogiku-install-key)

(defun kogiku-uninstall-key ()
  (when (and (eq minibuffer-completion-table 'read-file-name-internal)
             (eq (lookup-key (current-local-map) kogiku-completion-key)
                 'kogiku-complete)))
  (define-key (current-local-map) kogiku-completion-key kogiku-original-function))
(add-hook 'minibuffer-exit-hook 'kogiku-uninstall-key)    

(provide 'kogiku)
;; kogiku.el ends here