CVSROOT/scripts/cvs-commitmail.pl

#! /usr/bin/perl

# Usage: cvs-commitmail [-u user] [[-m mailto] ...] [-s] [-V] 'dirname file ...'
#
#       -u user         - $USER passed from loginfo
#       -m mailto       - for each user to receive cvs log reports
#                       (multiple -m's permitted)
#       -s              - to prevent "cvs status -v" messages
#       -V              - without '-s', don't pass '-v' to cvs status
#       -d              - attatch diffs.
#
# On CVSROOT/loginfo
#
#    # for cvs version 1.11.x or former
#    modulename /usr/bin/cvs-commitmail -d -m user@example.com %{sVv}
#
#    # for cvs version 1.12.x or later
#    modulename /usr/bin/cvs-commitmail -d -m user@example.com "%p %{sVv}"
#

# here is what the output looks like:
#
#    From: commituser@cvs.example.com
#    Subject: CVS update: modulename
#
#    Date: Wednesday November 23, 1994 @ 14:15
#    Author: woods
#
#    Update of /cvsroot/modulename
#    In directory cvs:/tmp/cvs-serv0001
#    
#    Modified Files:
#       test3 
#    Added Files:
#       test6 
#    Removed Files:
#       test4 
#    Log Message:
#    - wow, what a test
#
# (and for each file the "cvs status -v" output is appended unless -s is used)
#
#    ==================================================================
#    File: test3                Status: Up-to-date
#    
#       Working revision:       1.41    Wed Nov 23 14:15:59 1994
#       Repository revision:    1.41    /cvsroot/modulename/test3,v
#       Sticky Options: -ko
#    
#       Existing Tags:
#       local-v2                        (revision: 1.7)
#       local-v1                        (revision: 1.1.1.2)
#       CVS-1_4A2                       (revision: 1.1.1.2)
#       local-v0                        (revision: 1.2)
#       CVS-1_4A1                       (revision: 1.1.1.1)
#       CVS                             (branch: 1.1.1)

use strict;
use IO::File;
use POSIX;
use Jcode;

umask(002);

`cvs --version` =~ /(\d+\.\d+\.\d+)/;
my $cvsversion = $1;

my $cvsroot = $ENV{'CVSROOT'};
my $dostatus = 1;
my $showstatus = 1;
my $verbosestatus = 1;
my @users;
my $showdiff = 0;
my $showurl = 0;
my $login;
my $donefiles;
my $logfile;
my @files;
my $cvsweb_url = 'http://cvs.sourceforge.jp/cgi-bin/viewcvs.cgi/samurai-graph/';

# turn off setgid
$) = $(;

# parse command line arguments
while (@ARGV) {
        my $arg = shift @ARGV;

        if ($arg eq '-m') {
                push(@users, shift @ARGV);
        } elsif ($arg eq '-u') {
                $login = shift @ARGV;
        } elsif ($arg eq '-f') {
                ($logfile) && die "Too many '-f' args";
                $logfile = shift @ARGV;
        } elsif ($arg eq '-s') {
                $showstatus = 0;
        } elsif ($arg eq '-V') {
                $verbosestatus = 0;
        } elsif ($arg eq '-d') {
                $showdiff = 1;
        } elsif ($arg eq '-c') {
                $showurl = 1;
        } else {
                ($donefiles) && die "Too many arguments!\n";
                $donefiles = 1;
                @files = split(/ /, $arg);
        }
}

# the first argument is the module location relative to $CVSROOT
my $modulepath = shift @files;
my $subject = "CVS update: $modulepath";
my $str = "";
my $diffstr = "";

# get a login name for the guy doing the commit....
if ($login eq '') {
        $login = getlogin || (getpwuid($<))[0] || "nobody";
}

$str .= strftime("Date:\t%A %B %d, %Y @ %H:%M\n", localtime);
$str .= "Author:\t$login\n\n";

# print the stuff from logmsg that comes in on stdin to the logfile
my $infh = new IO::File "< -";
foreach ($infh->getlines) {
        $str .= Jcode->new($_)->h2z->jis;
}
undef $infh;
$str .= "\n";

# after log information, do an 'cvs -Qq status -v' on each file in the arguments.
if ($dostatus != 0) {
        while (@files) {
                my $newrev = '';
                my $oldrev = '';
                my $file = '';
                if ($showdiff || $showurl) {
                        if ($cvsversion =~ /^1\.11\./) {
                                my @filenames = split(/,/, shift @files);
                                $newrev = pop(@filenames);
                                $oldrev = pop(@filenames);
                                $file = join(',', @filenames);
                                undef @filenames;
                        } else {
                                $file = shift @files;
                                $oldrev = shift @files;
                                $newrev = shift @files;
                        }
                } else {
                        $file = shift @files;
                }
                if ($file eq "-") {
                        $str .= "[input file was '-']\n";
                        last;
                }

                if ($showstatus) {
                    my $rcsfh = new IO::File;
                    my $pid = $rcsfh->open ("-|");
                    if ( !defined $pid )
                    {
                        die "fork failed: $!";
                    }
                    if ($pid == 0)
                    {
                        my @command = ('cvs', '-nQq', 'status');
                        if ($verbosestatus)
                        {
                            push @command, '-v';
                        }
                        push @command, $file;
                        exec @command;
                        die "cvs exec failed: $!";
                    }
                    my $line;
                    while ($line = $rcsfh->getline) {
                        $str .= $line;
                    }
                    undef $rcsfh;
                    undef $pid;
                }

# added cvsweb url
                if ($showurl) {
                    $str .= "$modulepath/$file $oldrev -> $newrev (";
                    if ($oldrev eq 'NONE') {
                        $str .= 'added';
                    } elsif ($newrev eq 'NONE') {
                        $str .= 'removed';
                    } else {
                        $str .= 'modified';
                    }
                    $str .= ")\n";
                    $str .= "$cvsweb_url$modulepath/$file";
                    if ($oldrev eq 'NONE' || $newrev eq 'NONE') {
                        $str .= "?rev=";
                        if ($oldrev eq 'NONE'){
                            $str .= "$newrev";
                        } else { 
                            $str .= "$oldrev"; 
                        }
                        $str .= '&content-type=text/vnd.viewcvs-markup';
                        $str .= "\n";
                    } else {
                        $str .= ".diff?r1=$oldrev&r2=$newrev\n";
                    }
                }

                if ($showdiff) {
                        my $rcsfh = new IO::File;
                        my $pid = $rcsfh->open ("-|");
                        if ( !defined $pid ) {
                                die "fork failed: $!";
                        }
                        if ($pid == 0) {
                                my @command = ('cvs', '-nQq', 'rdiff', '-u');
                                if ($oldrev eq "NONE") {
                                        push @command, "-r0";
                                } else {
                                        push @command, "-r${oldrev}";
                                }
                                push @command, "-r${newrev}"
                                        if ($newrev ne "NONE");
                                push @command, "${modulepath}/${file}";
                                exec @command;
                                die "cvs exec failed: $!";
                        }
                        my $line;
                        while ($line = $rcsfh->getline) {
                                $diffstr .= $line;
                        }
                        undef $rcsfh;
                }
        }
}

my @mailcmd = ('mime-construct', '--to', join(',', @users), '--subject', $subject, '--type', 'text/plain', '--encoding' , '7bit', '--string', $str);
if ($showdiff) {
        push(@mailcmd, '--type', 'text/plain', '--encoding', '8bit', '--string', $diffstr);
}
system(@mailcmd);

exit 0;