satellite/satellite4/configure.in

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_PREREQ(2.59)
AC_INIT(satellite, 4.2.3, okumura@brain.riken.go.jp)
AC_REVISION($Id: configure.in,v 1.18 2006/09/04 13:51:18 orrisroot Exp $)

AC_CONFIG_SRCDIR([satellite4-config.in])
AC_CONFIG_AUX_DIR([config])
AC_PREFIX_DEFAULT([/usr/local/satellite4])

AC_GNU_SOURCE
AC_ISC_POSIX
AC_CYGWIN

AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)
AM_CONFIG_HEADER([config.h])

sl4includedir=$includedir/satellite4
AC_SUBST(sl4includedir)

sl4libdir=$libdir
AC_SUBST(sl4libdir)

sl4libexecdir=$libexecdir/satellite4
AC_SUBST(sl4libexecdir)

docdir=$datadir/doc
AC_SUBST(docdir)
sl4docdir=$docdir/satellite4
AC_SUBST(sl4docdir)

sl4sharedir=$datadir/satellite4
AC_SUBST(sl4sharedir)

examplesdir=$datadir/examples/satellite4
AC_SUBST(examplesdir)

moduledir=$libdir/satellite4
AC_SUBST(moduledir)

systemrcdir=$sysconfdir/satellite4
AC_SUBST(systemrcdir)

modulercdir=$sysconfdir/satellite4
AC_SUBST(modulercdir)

# Checks for programs.
AM_DISABLE_STATIC
AC_PROG_CXX
AC_PROG_CC
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
AC_PROG_RANLIB
AC_PROG_YACC
AC_PROG_AWK
AC_LIBTOOL_DLOPEN
AC_PROG_LIBTOOL
AM_PROG_LEX
AC_SHLIBPATH_VAR

AC_C_BIGENDIAN
AM_MAINTAINER_MODE

# Checks for libraries.
# FIXME: Replace `main' with a function in `-lm':
AC_CHECK_LIB(m, sin)

# check pthread library
ACX_PTHREAD
# Some platforms use these, so just defineed them.  They can't hurt if they
# are not supported.
PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
# At this point, we don't want to muck with the compiler name for threading.
# Let's see who fails, perhaps AIX.  2004-04-23
if test "$PTHREAD_CC" != "$CC"; then
AC_MSG_ERROR([
satellite4 does not support platforms that require a special
compiler binary for thread-safety.
])
fi

# check termcap library
AM_PATH_TERMCAP
# check X Toolkit
AM_PATH_XTOOLKIT

# FIXME: Replace `main' with a function in `-lsatellite':
#AC_CHECK_LIB([satellite], [main])
# FIXME: Replace `main' with a function in `-lslshell':
#AC_CHECK_LIB([slshell], [main])
AC_CHECK_LIB([dl], [dlopen])

# Checks for header files.
# libsl4 : direct.h pthread.h pwd.h stdlib.h string.h sys/param.h sys/stat.h 
#          sys/time.h sys/types.h unistd.h
AC_HEADER_DIRENT
AC_HEADER_STDBOOL
AC_HEADER_STDC
AC_HEADER_SYS_WAIT
AC_HEADER_TIME
AC_CHECK_HEADERS([direct.h pthread.h pwd.h stdlib.h string.h sys/param.h sys/stat.h sys/time.h sys/types.h unistd.h \
                  fcntl.h float.h locale.h malloc.h stddef.h stdlib.h string.h strings.h sys/file.h sys/ioctl.h sys/time.h sys/timeb.h \
                  termios.h vfork.h errno.h limits.h memory.h getopt.h pwd.h \
                  windows.h io.h process.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_C_INLINE
AC_TYPE_MODE_T
AC_TYPE_OFF_T
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_TYPE_SIGNAL
AC_TYPE_UID_T
AC_STRUCT_TM
AC_CHECK_TYPE(ssize_t, int)
AC_CHECK_TYPE(time_t, long)
dnl sig_t is the type of a signal handler (4.4BSD)
AC_CHECK_TYPES(sig_t, , ,
  [#include <sys/types.h>
   #include <signal.h> ])
AH_BOTTOM(
[#ifndef HAVE_SIG_T
typedef RETSIGTYPE (*sig_t) ();
#endif])

# Checks for library functions.
# libsl4 : endpwent getcwd memmove memset mkdir putenv rmdir setenv snprintf
#          strstr vasprintf vsnprintf wvsprintf _vscprintf
AC_FUNC_CLOSEDIR_VOID
AC_FUNC_FORK
AC_PROG_GCC_TRADITIONAL
AC_FUNC_LSTAT
AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
AC_FUNC_MALLOC
AC_FUNC_MMAP
AC_FUNC_REALLOC
AC_FUNC_STAT
AC_FUNC_STRTOD
AC_FUNC_VPRINTF
AC_CHECK_FUNCS([endpwent getcwd memmove memset mkdir putenv rmdir setenv snprintf strstr vasprintf vsnprintf wvsprintf _vscprintf \
                floor ftime gethostname gettimeofday munmap pow setlocale sqrt strchr strdup strpbrk strrchr strtol lrand48 \
                bzero strerror strncpy lockf flockf])

# replaced cflags and libs for pthread support
CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
CXXFLAGS="$CXXFLAGS $PTHREAD_CFLAGS"
LIBS="$PTHREAD_LIBS $LIBS"

AC_CONFIG_FILES([Makefile
                 satellite4-config
                 lib/Makefile
                 lib/libsl4/Makefile
                 lib/common/Makefile
                 lib/shell/Makefile
                 shell/Makefile
                 etc/Makefile
                 modules/Makefile
                 modules/util/Makefile
                 modules/system/Makefile
                 modules/ispp/Makefile
                 modules/gpm/Makefile
                 modules/gpm/lib/Makefile
                 modules/gpm/command/Makefile
                 modules/gpm/gpm2ps/Makefile
                 modules/gpm/gpmwin/Makefile
                 modules/bps/Makefile
                 modules/bps/command/Makefile
                 modules/ncs/Makefile
                 modules/ncs/lib/Makefile
                 modules/ncs/lib/common/Makefile
                 modules/ncs/lib/simulation/Makefile
                 modules/ncs/lib/main/Makefile
                 modules/ncs/command/Makefile
                 modules/ncs/ncspp/Makefile
                 modules/npe/Makefile
                 modules/npe/lib/Makefile
                 modules/npe/lib/common/Makefile
                 modules/npe/lib/estimation/Makefile
                 modules/npe/lib/user/Makefile
                 modules/npe/lib/ncs/Makefile
                 modules/npe/command/Makefile
                 modules/dcm/Makefile
                 modules/statistics/Makefile
                 modules/statistics/script/Makefile
                 modules/statistics/script/data/Makefile])
AC_OUTPUT