scim-ruby/scim-ruby/configure.ac

# Process this file with autoconf to produce a configure script.
AC_INIT(scim-ruby, 20061123, bluedwarf@bpost.plala.or.jp)
AC_CONFIG_SRCDIR([configure.ac])

# Save this value here, since automake will set cflags and cxxflags later
cflags_set=${CFLAGS+set}
cppflags_set=${CPPFLAGS+set}

# Init automake stuff
AM_INIT_AUTOMAKE
AM_CONFIG_HEADER(config.h)

# Init gettext
ALL_LINGUAS="ja"
AM_GNU_GETTEXT

GETTEXT_PACKAGE=scim-ruby
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [The gettext domain])

# Init libtool
AC_LIBTOOL_DLOPEN
AC_PROG_LIBTOOL
AC_LIB_LTDL
AC_SUBST(LIBTOOL_DEPS)

# Checks for programs.
AC_PROG_CXX
AC_PROG_CC
AC_LANG(C++)

AC_C_CONST
AC_TYPE_SIZE_T

# Checks for libraries.

SCIM_VERSION=0.99.8

PKG_CHECK_MODULES(SCIM,[scim >= $SCIM_VERSION])

# Check if we should build setup module
PKG_CHECK_MODULES(SCIM_GTKUTILS,[scim-gtkutils >= $SCIM_VERSION],
                                [SCIM_HAS_GTKUTILS=yes],
                                [SCIM_HAS_GTKUTILS=no])


AC_SUBST(SCIM_VERSION)

AM_CONDITIONAL(SCIM_BUILD_SETUP, [test "$SCIM_HAS_GTKUTILS" = "yes"])

if test "$SCIM_HAS_GTKUTILS" = "yes"; then
  SCIM_BUILD_SETUP=1
else
  SCIM_BUILD_SETUP=0
fi

AC_SUBST(SCIM_BUILD_SETUP)

# Checks for header files.
AC_HEADER_STDC
AC_FUNC_ALLOCA
AC_CHECK_HEADERS([argz.h fcntl.h float.h inttypes.h langinfo.h libintl.h limits.h locale.h malloc.h stddef.h stdint.h stdio_ext.h stdlib.h string.h strings.h sys/param.h unistd.h wchar.h])

# Checks for library functions.
AC_SUBST(ac_aux_dir)

# libtool option to control which symbols are exported
# right now, symbols starting with _ are not exported
LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
AC_SUBST(LIBTOOL_EXPORT_OPTIONS)

# Extra args.
AC_ARG_ENABLE(debug,
              [  --enable-debug     Turn on debugging],
              [case "${enableval}" in
               yes) debug=yes ;;
               no)  debug=no ;;
               *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
              esac],[debug=no])

if test "x$debug" = "xyes"; then
  test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
  test "$cppflags_set" = set || CPPFLAGS="$CXXFLAGS -g"
  SCIM_DEBUG_FLAGS="-DENABLE_DEBUG=1"
else
  SCIM_DEBUG_FLAGS=""
fi
AC_SUBST(SCIM_DEBUG_FLAGS)

# obsolete clipboard function, now this depends on an external command
dnl AC_ARG_ENABLE(clipboard,
dnl           [  --enable-clipboard     Use clipboard (requires Gtk+)],
dnl           [case "${enableval}" in
dnl            yes) clipboard=yes ;;
dnl            no)  clipboard=no ;;
dnl            *) AC_MSG_ERROR(bad value ${enableval} for --enable-clipboard) ;;
dnl            esac],[clipboard=yes])

dnl if test "x$clipboard" = "xyes"; then
dnl    # Check gtk2
dnl    PKG_CHECK_MODULES(GTK2, [gtk+-2.0 >= 2.6.0],
dnl                            [HAS_GTK=yes],
dnl                        [HAS_GTK=no])

dnl    if test "$HAS_GTK" = "yes"; then
dnl       SCIM_RUBY_CLIPBOARD_FLAG="-DENABLE_CLIPBOARD"
dnl       GTK2_CFLAGS=`$PKG_CONFIG --cflags gtk+-2.0`
dnl       GTK2_LIBS=`$PKG_CONFIG --libs gtk+-2.0`
dnl    else
dnl       SCIM_RUBY_CLIPBOARD_FLAG="-UENABLE_CLIPBOARD"
dnl    fi
dnl else
dnl    SCIM_RUBY_CLIPBOARD_FLAG="-UENABLE_CLIPBOARD"
dnl fi
dnl AC_SUBST(SCIM_RUBY_CLIPBOARD_FLAG)

SCIM_ICONDIR=`$PKG_CONFIG --variable=icondir scim`
SCIM_MODULEDIR=`$PKG_CONFIG --variable=moduledir scim`

if test "x$SCIM_ICONDIR" = "x"; then
  SCIM_ICONDIR=${datadir}/scim/icons
fi

if test "x$SCIM_MODULEDIR" = "x"; then
  SCIM_MODULEDIR=${libdir}/scim-1.0
fi

if test "x$SCIM_RUBYDIR" = "x"; then
   SCIM_RUBYDIR=${datadir}/scim/scim-ruby
fi

AC_SUBST(SCIM_ICONDIR)
AC_SUBST(SCIM_MODULEDIR)
AC_SUBST(SCIM_RUBYDIR)
        
AC_CONFIG_FILES([
Makefile
intl/Makefile
po/Makefile.in
m4/Makefile
src/Makefile
data/Makefile
])

AC_OUTPUT