xoonips/AL/configure.in

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_PREREQ([2.59])
AC_REVISION($Id: configure.in,v 1.7 2005/12/10 11:55:02 orrisroot Exp $)

AC_INIT([xnpal], [1.0.0], [software@ni.brain.riken.jp])

AC_CONFIG_SRCDIR([account.cc])
AM_CONFIG_HEADER([config.h])
AC_CONFIG_AUX_DIR(config)
AC_CANONICAL_TARGET
AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)


AM_MAINTAINER_MODE

# Checks for programs.
AM_DISABLE_STATIC
AC_PROG_CXX
AC_PROG_CC
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
AC_PROG_RANLIB
AC_LIBTOOL_DLOPEN
AC_PROG_LIBTOOL

AM_XNI_PATH_XML2([2.6.17])
AM_PATH_IODBC([3.0.6])
AM_PATH_UNIXODBC([2.2.9])
AM_PATH_ZLIB
AM_PATH_OPENSSL
AM_PATH_PHP([4.3.2])

ODBC_CFLAGS=""
ODBC_LIBS=""
if test x"$UNIXODBC_LIBS" = x ; then
  if test x"$IODBC_LIBS" = x ; then
    AC_MSG_ERROR([odbc library required but not found])
  else
    ODBC_CFLAGS="$IODBC_CFLAGS"
    ODBC_LIBS="$IODBC_LIBS"
  fi
else
  ODBC_CFLAGS="$UNIXODBC_CFLAGS"
  ODBC_LIBS="$UNIXODBC_LIBS"
fi

XNPAL_CFLAGS="$XML_CPPFLAGS $ODBC_CFLAGS $ZLIB_CFLAGS $OPENSSL_CFLAGS"
XNPAL_LIBADD="$XML_LIBS $ODBC_LIBS $ZLIB_LIBS $OPENSSL_LIBS"

AC_SUBST([XNPAL_CFLAGS])
AC_SUBST([XNPAL_LIBADD])

dnl check mysql charset for 4.1 or higher
AC_MSG_CHECKING([if mysql charset setting wanted])
AC_ARG_WITH(mysql-charset, AC_HELP_STRING([--with-mysql-charset], [Set MySQL charset (for version 4.1 or higher)]), mysql_charset="$withval", mysql_charset="")
if test x-$mysql_charset != "x-"; then
  AC_MSG_RESULT([yes ($mysql_charset)])
  AC_DEFINE_UNQUOTED(MYSQL_CHARSET,"$mysql_charset",[mysql charset])
  AC_DEFINE(USE_MYSQL_CHARSET,,[mysql charset setting required])
else
  AC_MSG_RESULT(no)
fi
AC_SUBST([MYSQL_CHARSET])
AC_SUBST([USE_MYSQL_CHARSET])

dnl check where to log
AC_MSG_CHECKING(if logging to syslog wanted)
AC_ARG_ENABLE(syslog, AC_HELP_STRING([--enable-syslog], [Enable logging to syslog]), syslog=yes)
if test x-$syslog = "x-yes"; then
   AC_MSG_RESULT(yes)
   AC_DEFINE(USE_SYSLOG,,[logging to syslog enabled])
else
  AC_MSG_RESULT(no)
fi
AC_SUBST(USE_SYSLOG)

# Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS([arpa/inet.h fcntl.h netinet/in.h stddef.h stdlib.h string.h sys/socket.h syslog.h unistd.h utime.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_SIZE_T
AC_STRUCT_TM
AC_CHECK_TYPE(time_t, long)

# Checks for library functions.
AC_FUNC_MALLOC
AC_FUNC_STAT
AC_FUNC_STRTOD
AC_CHECK_FUNCS([memset strchr strncasecmp])

AC_CONFIG_FILES([Makefile xnpal-config])
AC_OUTPUT