flexmark-ext-inline-tags/trunk/build.gradle

plugins {
    id "com.jfrog.bintray" version "1.8.5"
}
apply plugin : 'maven-publish'

apply plugin: 'java'

group = 'net.osdn.blogs.flexmark.ext'
archivesBaseName = 'flexmark-ext-inline-tags'
version = '0.3.1'

tasks.withType(JavaCompile) {
        sourceCompatibility = 1.7
        targetCompatibility = 1.7
        options.compilerArgs << '-Xlint:all'
}

def defaultEncoding = 'UTF-8'
tasks.withType(AbstractCompile).each { it.options.encoding = defaultEncoding }
tasks.withType(GroovyCompile).each { it.groovyOptions.encoding = defaultEncoding }

javadoc {
        options.charSet = defaultEncoding
        options.encoding = defaultEncoding
        options.memberLevel = JavadocMemberLevel.PUBLIC
        options.stylesheetFile = new File(rootDir, 'javadoc.css')
}

repositories {
        jcenter()
}

dependencies {
        implementation 'com.vladsch.flexmark:flexmark:0.62.2'
}

defaultTasks 'clean', 'build'

task sourcesJar(type: Jar, dependsOn: classes) {
        setGroup('build')
        setDescription('Assembles a jar archive containing the main source code.')
        archiveClassifier = 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
        setGroup('documentation')
        setDescription('Generates Javadoc API documentation as a jar archive.')
        archiveClassifier = 'javadoc'
    from javadoc.destinationDir
}

// For Bintray maven repository
// Use publishing -> bintrayUpload task.

artifacts {
    archives sourcesJar
    archives javadocJar
}

publishing {
        publications {
                mavenJava(MavenPublication) {
                        from components.java
                        artifact sourcesJar
                        artifact javadocJar
                }
        }
}
bintray {
        user = System.getenv('BINTRAY_USER')
        key  = System.getenv('BINTRAY_KEY')
        
        publications = ['mavenJava']
        
        pkg {
                repo = 'maven'
                name = 'flexmark-ext-inline-tags'
                licenses = ['BSD 2-Clause']
        vcsUrl = 'https://svn.osdn.net/svnroot/blogs/flexmark-ext-inline-tags'
        }
}