jpki-pdf-signer/trunk/build.gradle

apply plugin: 'java'

version = '1.2.7'

tasks.withType(JavaCompile) {
        sourceCompatibility = 11
        targetCompatibility = 11
        options.compilerArgs << '-Xlint:all'
}

repositories {
        mavenCentral()
}

dependencies {
        implementation fileTree(dir: 'lib',
                        includes: ['**/*.jar'],
                        excludes: ['**/*-sources.jar', '**/*-javadoc.jar'])

        implementation 'org.apache.pdfbox:pdfbox:2.0.27'
        implementation 'org.apache.pdfbox:fontbox:2.0.27'

        implementation 'com.fasterxml.jackson.core:jackson-databind:2.14.1'

        implementation 'org.kordamp.ikonli:ikonli-javafx:12.3.1'
        implementation 'org.kordamp.ikonli:ikonli-materialdesign-pack:12.3.1'

        // jpki-wrapper dependencies
        runtimeOnly 'org.bouncycastle:bcpkix-jdk18on:1.72'
        runtimeOnly 'net.java.dev.jna:jna:5.12.1'
        runtimeOnly 'net.java.dev.jna:jna-platform:5.12.1'
}

sourceSets.main.resources {
        srcDirs = ['src/main/resources', 'src/main/java' ]
}

def defaultEncoding = 'UTF-8'
tasks.withType(AbstractCompile).each { it.options.encoding = defaultEncoding }
tasks.withType(GroovyCompile).each { it.groovyOptions.encoding = defaultEncoding }

defaultTasks 'clean', 'build', 'exewrap'

jar {
        manifest {
                attributes "Specification-Version": "${project.version}"
                attributes "Main-Class" : "net.osdn.jpki.pdf_signer.Main"
                attributes "Class-Path": sourceSets.main.runtimeClasspath.collect { "lib/$it.name" }.join(' ')
        }
        into('net/osdn/jpki/pdf_signer') {
                from("${projectDir}") {
                        include('LICENSE.txt')
                }
        }
}

task copyLibraries(type: Copy) {
        setGroup("build")
        setDescription("Copy dependency libraries.")
        from (sourceSets.main.runtimeClasspath) {
                include '*.jar'
        }
        from('lib') {
                include '*.dll'
        }
        into "${buildDir}/package/lib/"
}

task createJavaRuntime(type: Exec, dependsOn: ['jar', 'copyLibraries']) {
        setGroup("build")
        setDescription("Create Java Runtime.")
        workingDir "${buildDir}/package/"
        commandLine 'cmd', '/c', 'CreateJRE.bat', "${jar.archiveFile.get()}", "lib", "-server"
}

task exewrap(type: Exec, dependsOn: 'jar') {
        setGroup("build")
        setDescription('Assembles the executable.')
        executable "${projectDir}/etc/exewrap.exe"
        args "-A", "x64",
                        "-g",
                        "-t", "11",
                        "-a", "-Xms256m -Xmx768m",
                        "-e", "SHARED",
                        "-j", "${jar.archiveFile.get()}",
                        "-i", "etc/ico/app.ico",
                        "-o", "${buildDir}/package/${archivesBaseName}.exe",
                        "-p", "JPKI PDF SIGNER",
                        "-d", "JPKI PDF SIGNER",
                        "-c", "(C) 2017-2023 HIRUKAWA Ryo",
                        "-V", "${version}",
                        "-v", "${version}"
}