mmaid/trunk/configure.ac

dnl Process this file with autoconf to produce a configure script.
AC_INIT(src/mmaid.c)
PACKAGE=mmaid

dnl version number
MAJOR_VERSION=0
MINOR_VERSION=4
MICRO_VERSION=5
EXTRA_VERSION=
VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION$EXTRA_VERSION

AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
AC_DEFINE_UNQUOTED(PACKAGE,"$PACKAGE")
AC_DEFINE_UNQUOTED(VERSION,"$VERSION")

AC_USE_SYSTEM_EXTENSIONS
AC_CONFIG_MACRO_DIR([m4])

dnl Getting the Canonical System Type
AC_CANONICAL_HOST
AC_DEFINE_UNQUOTED(BUILD_ENVIRONMENT,"${host}",Define to the build environment.)

dnl Specify a header configuration file
AM_CONFIG_HEADER(config.h)

dnl **************************************************************
dnl Checks for programs.
dnl **************************************************************
AC_C_BIGENDIAN
AC_ISC_POSIX
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_MAKE_SET
AM_MAINTAINER_MODE

dnl **************************************************************
dnl libtool
dnl **************************************************************
AC_ENABLE_SHARED(yes)
AC_ENABLE_STATIC(no)
AM_PROG_LIBTOOL

dnl **************************************************************
dnl Check for GTK+.
dnl **************************************************************
AM_PATH_GTK_2_0(2.0.0,,AC_MSG_ERROR(Test for GTK+-2.0 failed.))

dnl **************************************************************
dnl Check for Mime globs file.
dnl **************************************************************
AC_ARG_ENABLE(mime,
  [  --enable-mime[=FILE]      Enable mime globs file])
if test -z "$enable_mime" || test "$enable_mime" = 'yes'; then
  if test -f "${datadir}/mime/globs"; then
    mimefile="${datadir}/mime/globs"
  elif test -f '/usr/local/share/mime/globs'; then
    mimefile='/usr/local/share/mime/globs'
  elif test -f '/usr/share/mime/globs'; then
    mimefile='/usr/share/mime/globs'
  elif test "$enable_mime" = 'yes'; then
    mimefile="${datadir}/mime/globs"
  fi
elif test "$enable_mime" != 'no'; then
  mimefile="$enable_mime"
fi
if test -n "$mimefile"; then
  enable_mime='yes'
else
  enable_mime='no'
fi
AM_CONDITIONAL(ENABLE_MIME,test "$enable_mime" = 'yes')
AC_SUBST(mimefile)

dnl **************************************************************
dnl add /usr/local/include to $CFLAGS.
dnl Only when the directory exists and it wasn't there yet.
dnl **************************************************************
if test -d /usr/local/include; then
  tt=`echo "$CFLAGS" | sed -e 's+-I/usr/local/include ++g' -e 's+-I/usr/local/include$++g'`
  if test "$tt" = "$CFLAGS"; then
    CFLAGS="$CFLAGS -I/usr/local/include"
  fi
fi
if test -d /usr/local/lib; then
  tt=`echo "$CFLAGS" | sed -e 's+-L/usr/local/lib ++g' -e 's+-L/usr/local/lib$++g'`
  if test "$tt" = "$CFLAGS"; then
    CFLAGS="$CFLAGS -L/usr/local/lib"
  fi
fi

dnl **************************************************************
dnl Check for sysconfdir.
dnl **************************************************************
AC_SUBST(sysconfdir)

dnl **************************************************************
dnl Check for gettext.
dnl **************************************************************
ALL_LINGUAS='ja'
  my_save_CFLAGS="$CFLAGS"
AC_CHECK_LIB(intl, libintl_nl_domain_bindings, CFLAGS="$CFLAGS -D_nl_domain_bindings=libintl_nl_domain_bindings")
AM_GNU_GETTEXT
  CFLAGS="$my_save_CFLAGS"
AC_CHECK_FUNC(gettext,,AC_CHECK_LIB(intl,gettext))
localedir="${datadir}/locale"
AC_SUBST(localedir)

dnl **************************************************************
dnl Checks for header files.
dnl **************************************************************
AC_HEADER_STDBOOL
AC_CHECK_HEADERS(arpa/inet.h arpa/nameser.h complex.h dirent.h fcntl.h netdb.h netinet/in.h resolv.h stdint.h sys/file.h sys/mman.h sys/param.h sys/select.h sys/socket.h sys/stat.h sys/time.h sys/timeb.h sys/types.h unistd.h utime.h)

dnl **************************************************************
dnl Checks for typedefs and structures.
dnl **************************************************************
AC_C_CONST
AC_C_VOLATILE
AC_STRUCT_TM
AC_TYPE_SIZE_T

dnl **************************************************************
dnl Checks for compiler characteristics.
dnl **************************************************************
if test "$GCC" = 'yes'; then
  CFLAGS="$CFLAGS -Wall"
fi
if $LD --help 2> /dev/null | grep as-needed > /dev/null; then
  LDFLAGS="$LDFLAGS -Wl,--no-as-needed"
fi

dnl **************************************************************
dnl Checks for library functions.
dnl **************************************************************
AC_FUNC_ALLOCA
AC_FUNC_MEMCMP
AC_FUNC_MKTIME
AC_FUNC_SETVBUF_REVERSED
AC_FUNC_STAT
AC_FUNC_LSTAT
AC_FUNC_STRCOLL
AC_FUNC_STRFTIME
AC_FUNC_VPRINTF
AC_CHECK_FUNCS(asprintf clock_gettime flock ftruncate getcwd gettimeofday gmtime_r kill lstat nanosleep setenv sleep timegm tzset unsetenv usleep utime vasprintf)

AC_OUTPUT([
Makefile
Makefile.msc
intl/Makefile
iwmcrt/Makefile
po/Makefile.in
gcommon/Makefile
misc/Makefile
orz/Makefile
src/Makefile
])

dnl **************************************************************
dnl Show some info.
dnl **************************************************************
AC_MSG_RESULT([
Configure Result :

   Package      : ${PACKAGE}
   Version      : ${VERSION}
   C Compiler   : ${CC} ${CFLAGS}
   Install path : ${prefix}
   Config       : ${sysconfdir}
   Locale       : ${localedir}
   Mime globs   : ${mimefile}
   Environment  : ${host}
])