trunk/Toriya/rxdriver.v

////////////////////////////////////////////////////////////////
// Serial RxD - 単純なシリアル受信
// author: 中村 巧 <webmaster@chapuni.com>
// $Id$

module rxdriver(clk, rst,
                RxD, RTS,
                rdy, d, ack);
input clk;      // x4
input rst;
input RxD;      // 受信データ
output RTS;     // 受信要求(負論理)
output rdy;     // d にデータが載ってるときにアサートされる
output [7:0] d;
input ack;      // d をフェッチしてほしいときにアサートせよ

// サンプリングキュー(4 * 10 - いくつか)
// エンドビットを認識できればいいので、これで十分
parameter ENDBIT = 38;
reg [ENDBIT:0] q;

// フレームを受信している間アサートされる
reg f;

// 1-byte FIFO
reg [7:0] d;
reg rdy;        // FIFOに有効データがセットされてるときアサート

// ステートを表わす
wire qrdy;

// フレーム検出されているときにアサートされる
assign qrdy = q[0] && !q[3:1] && q[ENDBIT];

// 早めにRTSを出さないと、PCが余分に送りつけてきて
// overrunしてしまう。なのでFIFOが埋まって
// 次のフレームが始まったらネゲートする。
assign RTS = rdy && f;

always @(posedge clk or posedge rst)
if (rst)
begin
        q <= ~0;        // すべて1で埋めておく
        f <= 0;
        d <= ~0;
        rdy <= 0;       // FIFOは空
end
else
begin
        if (qrdy && !rdy && !ack)
        begin
                // キューをまっさらにする。
                // フレームの取り込みを続行するため
                q[ENDBIT] <= RxD;
                q[ENDBIT - 1:0] <= ~0;
                f <= 0;

                // キューからFIFOにフレームを取り込む
                d <= {  q[34], q[30], q[26], q[22],
                        q[18], q[14], q[10], q[ 6]};
                rdy <= 1;
        end
        else if (!qrdy)
        begin
                q <= {RxD, q[ENDBIT:1]};        // キューにサンプリング
                if (!RxD)
                        f <= 1;
        end

        // 外からデータが取り込まれたらrdyをネゲート
        if (rdy && ack)
                rdy <= 0;
end

endmodule