trunk/Toriya/txdriver.v

////////////////////////////////////////////////////////////////
// Serial TxD - 単純なシリアル送信
// author: 中村 巧 <webmaster@chapuni.com>
// $Id$

module txdriver(clk, rst,
                TxD, CTS,
                we, d, rdy);
input clk;      // x1
input rst;
output TxD;     // 送信データ
input CTS;      // 送信データ要求(負論理)

input we;       // d にデータを用意してアサートせよ。
input [7:0] d;  // data byte
output rdy;     // データを取り込めるときにアサートされる。

// フレームキューが空の状態は、これである。
// このとき、1が送信され続ける。
parameter EMPTY = 10'b0000000001;

// フレーム(10ビット)
reg [9:0] q;

// 常にフレームのLSBが送信され続ける。
// 何もしないときは、1 でドライブしておくべきである。
assign TxD = q[0];

// rdyは、ストップビットを送ってる最中にアサートされる。
assign rdy = (q == EMPTY || q[9:1] == 8'b00000001);

// ステート変数
// それぞれ排他的な条件である。
wire empty;
wire waitcts;

// キューにデータを取り込み可能な状態
// キューのシフトは行われない。
assign empty = (q == EMPTY);

// 送信許可が下りるのを待ってる状態
// このとき、q[8:1]は、送信待ちデータになっている。
assign waitcts = (q[9] && q[0]);

always @(posedge clk or posedge rst)
if (rst)
begin
        q <= EMPTY;
end
else if (empty)
begin
        // データがセットされるときは、ストップビットを立てておく
        // CTSに応じてスタートビットがセットされる
        if (we)
                q <= {1'b1, d, CTS};
        // CTS=1のときは、waitctsステートに移る
        // CTS=0のときは、txbitsステートに移る
end
else if (waitcts)
begin
        // CTS, 送信許可待ちの状態
        // CTS=0になったら自動的にtxbitsステートに
        // 移り、送信動作が開始される。
        q[0] <= CTS;    // start bit
end
else
begin
        // txbits - ストップビット(番人でもある)に突き当たるまで
        // キューをシフトする。キューのLSBはTxDに直結している
        // ので、送信が自動的に行われる。
        // MSBから0を充填していくので、ストップビットに
        // 突き当たったときに自動的にemptyステートに移行する。
        q <= {1'b0, q[9:1]};
end

endmodule