timerabbit/logger/Main.fx

/*
 * Copyright 2009 Junpei Kawamoto
 *
 * This file is part of TimeRabbit project TimeLogger.
 * TimeRabbit project TimeLogger is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * TimeRabbit project TimeLogger is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with TimeRabbit project TimeLogger.  If not, see <http://www.gnu.org/licenses/>.
 */
package org.timerabbit.logger;

import javafx.stage.Stage;
import javafx.scene.Scene;

import java.net.ProxySelector;

import java.net.Proxy;
import java.net.URI;

import java.net.InetSocketAddress;

import java.lang.System;

import java.lang.SecurityException;
import javafx.animation.Timeline;
import javafx.animation.KeyFrame;
import javafx.animation.Interpolator;

import org.timerabbit.util.Config;


try{ // ���������������������

        var selector: ProxySelector = ProxySelector.getDefault();
        var proxy: Proxy = selector.select(new URI("http://www.google.com")).get(0);
        println("System proxy setting for HTTP: {proxy.toString()}");
        if(proxy.type().equals(Proxy.Type.HTTP)){

                var addr: InetSocketAddress = proxy.address() as InetSocketAddress;
                System.setProperty("http.proxyHost", addr.getHostName());
                System.setProperty("http.proxyPort", addr.getPort().toString());

                println("Using http proxy: {addr.getHostName()}:{addr.getPort()}")

        }
        proxy = selector.select(new URI("https://www.google.com")).get(0);
        println("System proxy setting for HTTPS: {proxy.toString()}");
        if(proxy.type().equals(Proxy.Type.HTTP)){

                var addr: InetSocketAddress = proxy.address() as InetSocketAddress;
                System.setProperty("https.proxyHost", addr.getHostName());
                System.setProperty("https.proxyPort", addr.getPort().toString());

                println("Using https proxy: {addr.getHostName()}:{addr.getPort()}")

        }

}catch(e: SecurityException){

        System.err.println(e.getLocalizedMessage());

} // ���������������������

// ������������������������
var stageX: Number = 0;
var stageY: Number = 0;

// ���������������������
def config: Config = Config{};
if(config.get("x") != null){
        stageX = Number.valueOf(config.get("x"));
}
if(config.get("y") != null){
        stageY = Number.valueOf(config.get("y"));
}

var alpha: Number = 0;
def ConunterToPreference: Timeline = Timeline {
        keyFrames : [
                KeyFrame {
                        time : 0s
                        values: alpha => 0
                },
                KeyFrame {
                        time: 0.5s
                        values: alpha => 1.0 tween Interpolator.EASEBOTH
                }
        ]
}
def PreferenceToCounter: Timeline = Timeline {
        keyFrames : [
                KeyFrame {
                        time : 0s
                        values: alpha => 1.0
                },
                KeyFrame {
                        time: 0.5s
                        values: alpha => 0 tween Interpolator.EASEBOTH
                }
        ]
}


Stage{

    title: "TimeLogger : TimeRabbitProject"
        width: 360
    height: 240
        resizable: false

        x: bind stageX with inverse
        y: bind stageY with inverse

        def counter: Counter = Counter{ // ������������
                isTwitter: Boolean.valueOf(config.get("Twitter"))
                isGCal: Boolean.valueOf(config.get("GoogleCalendar"))
                disableTwitter: bind preference.startTweet.length() == 0 and preference.endTweet.length() == 0
                disableGCal: bind preference.gcalID.length() == 0;

                opacity: bind 1.0 - alpha;

                onConfig: function(){

                        preference.disable = false;
                        counter.disable = true;
                        ConunterToPreference.playFromStart();

                }

                onStart: function(title: String, start: Long){

                        if(counter.isTwitter and preference.startTweet.length() != 0){

                                SendTweet.send(preference.startTweet.replace("\{title\}", "{title}"));

                        }

                }

                onStop: function(title: String, start: Long, end: Long){

                        if(counter.isTwitter and preference.endTweet.length() != 0){

                                SendTweet.send(preference.endTweet.replace("\{title\}", "{title}"));

                        }

                        if(counter.isGCal){

                                SendCalendarEvent{
                                        id: config.get("GoogleCalendar.ID")
                                        password: config.get("GoogleCalendar.Password")
                                        url: preference.gcalID
                                        begin: start
                                        end: end
                                        title: title
                                }.start();

                        }

                }

        }; // ������������

        def preference: Preference = Preference{ // ������������

                // ���������������������������
                startTweet: config.get("Twitter.StartTweet")
                endTweet: config.get("Twitter.EndTweet")
                googleID: config.get("GoogleCalendar.ID")
                googlePassword: config.get("GoogleCalendar.Password")
                gcalName: config.get("GoogleCalendar.CalendarName")

                opacity: bind alpha
                translateX: 5
                translateY: 5

                // ������������������������������������������
                disable: true

                onOK : function(){
                        config.put("Twitter.startTweet", preference.startTweet);
                        config.put("Twitter.endTweet", preference.startTweet);
                        config.put("GoogleCalendar.ID", preference.googleID);
                        config.put("GoogleCalendar.Password", preference.googlePassword);
                        config.put("GoogleCalendar.CalendarName", preference.gcalName);

                        preference.disable = true;
                        counter.disable = false;
                        PreferenceToCounter.playFromStart();
                }

                onCancel : function(){
                        preference.startTweet = config.get("Twitter.StartTweet");
                        preference.endTweet = config.get("Twitter.EndTweet");
                        preference.googleID = config.get("GoogleCalendar.ID");
                        preference.googlePassword = config.get("GoogleCalendar.Password");
                        preference.gcalName = config.get("GoogleCalendar.CalendarName");

                        preference.disable = true;
                        counter.disable = false;
                        PreferenceToCounter.playFromStart();
                }

        }; // ������������

        scene : Scene{
                content: [counter, preference]
        }

        onClose: function(){
                config.put("x", stageX.toString());
                config.put("y", stageY.toString());
                config.put("Twitter", counter.isTwitter.toString());
                config.put("GoogleCalendar", counter.isGCal.toString());

                config.save();
        }

}